// This is a roxen module.
// by Azundris
// inspired by roxen foldlist.

constant cvs_version = "$Id: azoufold.pike,v 2.00 2002/02/27 06:47:43 azundris Exp $";
constant thread_safe=1;

#include <module.h>

inherit "module";
inherit "roxenlib";
inherit "state";

constant module_type = MODULE_PARSER;
constant module_name = "Azundris' folding lists";
constant module_doc  = "Provides the &lt;foldlist&gt; tag, which is used to "
"build folding lists. The folding lists work like <tt>&lt;dl&gt;</tt> lists "
"where each item can be folded or unfolded.";

TAGDOCUMENTATION
#ifdef manual
constant tagdoc=([

"foldlist":({#"<desc cont>
This tag is used to build folding lists, that are like &lt;dl&gt;
lists, but where each element can be unfolded. The tags used to build
the lists elements are ft and fd.
</desc>

<attr name=unfolded>
Will make all the elements in the list unfolded by default.
</attr>
",

(["ft":({#"<desc cont>
This tag is used within the foldlist tag. The contents of this
container, that is not within an fd, tag will be visible both when the
element is folded and unfolded.

<attr name=folded>
Will make this element folded by default. Overrides an unfolded
attribute set in the foldlist tag.
</attr>

<attr name=unfolded>
Will make this element unfolded by default.
</attr>

<attr name=foldedsrc>
Picture to flag a folded &lt;ft&gt;.
</attr>

<attr name=unfoldedsrc>
Picture to flag an unfolded &lt;ft&gt;.
</attr>

<attr name=textbg>
Background picture for the text.
</attr>

<attr name=iconbg>
Background picture for the folded/unfolded icon.
</attr>",

(["fd":#"<desc cont>
The contents of this container will only be visible when the element
it is written in is unfolded."])
  })])
})]);
#endif

string encode_url(array states, object state, RequestID id){
  string value="";

  foreach(states,int tmp) {
    if(tmp>-1)
      value+=(string)tmp;
    else
      return id->not_query+"?cmd=fold&v1="+
        state->uri_encode(value);
  }
  return id->not_query+"?cmd=fold&v1="+
    state->uri_encode(value);
}

//It seems like the fold/unfold images are mixed up.
private string tag_ft(string tag, mapping m, string cont, RequestID id, 
                      object state, mapping fl) 
{   int index=fl->cnt++;
    int co=0;
    array states=copy_value(fl->states);

    if(fl->section&&strlen(fl->section)) {
      string s=(cont/">")[1];
      s=(s/"<")[0];
      if(fl->section!=s)
        return "";
      co=strlen((lower_case(cont)/"<fd")[0]); }

    if(co || (m->unfolded && states[index]==-1) ||
      ((index<sizeof(states))&&(states[index]==1))) {
        fl->txt="";
        fl->states[index]=1;
        id->misc->foldlist_id=fl->inh+(fl->cnt>10?":":"")+(string)fl->cnt;
        states[index]=0;
        if(co) {
          cont=cont[co..];
          parse_html(cont,([]),(["fd":
                     lambda(string tag, mapping m, string cont) {
                            fl->txt+=parse_rxml(cont,id); return ""; } ]));
          return "<tr><td>"+fl->txt+"</td></tr>\n"; }

        return "<tr><td colspan=\"2\" background=\""+(string)fl->textbg+"\">"+
               (strlen(fl->textbg)?"<img alt=\"\" src=\""+(string)fl->textbg+"\">":"")+
               "<br /><font face=\"Helvetica,Arial\"> "+
               parse_html(cont,([]),(["fd":
                          lambda(string tag, mapping m, string cont) {
                                 fl->txt+=parse_rxml(cont,id); return ""; } ]))+
               "</font></td>"+
               "<td background=\""+(string)fl->iconbg+"\" "+
               "valign=\"top\" align=\"right\" rowspan=\"2\">"+
               (strlen(fl->fsrc)?
               "<a target=\"_self\" href=\""+
               encode_url(states,state,id)+
               "\"><img align=\"right\" height=\"20\" src=\""+
               (m->unfoldedsrc||fl->ufsrc)+
               "\" border=\"0\" alt=\"-\" /></a>":"")+"</td></tr>"+
               "<tr><td background=\""+(string)fl->textbg+"\">&nbsp;&nbsp;"+
               "</td><td background=\""+(string)fl->textbg+"\">"+
               "<font face=\"Helvetica,Arial\">"+fl->txt+"</font></td></tr>"; }

    if(index<sizeof(states)) {
      fl->states[index]=0;
      states[index]=1; }

    return "<tr><td colspan=\"2\" background=\""+(string)fl->textbg+"\">"+
           (strlen(fl->textbg)?"<img alt=\"\" src=\""+fl->textbg+"\">":"")+
           "<br /><font face=\"Helvetica,Arial\"> "+
           parse_html(cont,([]),(["fd":""]))+
           "</font></td><td background=\""+(string)fl->iconbg+"\">"+
           (strlen(fl->fsrc)?
           "<a target=\"_self\" href=\""+
           encode_url(states,state,id)+
           "\"><img align=\"right\" height=\"20\" src=\""+
           (m->foldedsrc||fl->fsrc)+
           "\" border=\"0\" alt=\"+\" /></a>":"")+"</td></tr></td></tr>"; }

string container_foldlist(string tag, mapping m, string c, RequestID id) {
  array states;
  int fds=sizeof(lower_case(c)/"<fd")-1;

  if(!id->misc->foldlist_id)
    id->misc->foldlist_id="";

  //Make an initial guess of what should be folded and what should not.
  if(m->unfolded)
    states=allocate(fds,1);  //All unfolded
  else if(m->folded)
    states=allocate(fds,0);  //All folded
  else
    states=allocate(fds,-1); //All unknown

  //Register ourselfs as state consumers and incorporate our initial state.
  string fl_name = (m->name || "fl")+fds+(id->misc->foldlist_id!=""?":"+id->misc->foldlist_id:"");
  object state=Page_state(id);
  string state_id = state->register_consumer(fl_name, id);
  if(!m->fixed) {
    if(id->misc->session_variables->fold)
      id->variables->state=id->misc->session_variables->fold;
    if(id->variables->state && !state->uri_decode(id->variables->state))
      RXML.run_error("Error in state."); }

  //Get our real state
  array new=(state->get(state_id)||"")/"";
  for(int i=0; i<sizeof(new); i++)
    states[i]=(int)new[i];

  mapping fl=(["states":states,
               "cnt":0,
               "inh":id->misc->foldlist_id,
               "txt":"",
               "textbg":m->textbg||"",
               "iconbg":m->iconbg||"",
               "section":m->section||"",
               "fsrc":m->foldedsrc||"/internal-roxen-unfold",
               "ufsrc":m->unfoldedsrc||"/internal-roxen-fold"]);

  //Do the real thing.
  c=parse_html(c,([]),(["ft":tag_ft]),id,state,fl);
  id->misc->foldlist_id=fl->inh;

  return (id->misc->debug?"<!-- "+state_id+" -->":"")+
          "\n\n<!-- automagic insert by azoufold -->\n"+
          c+
          "\n<!-- /automagic insert by azoufold -->\n\n"; }

// ends